set shell := ["fish", "-c"]

# Recette par défaut.
default: dev

# Liste toutes les recettes
list:
    @just --list --list-heading 'Recettes disponibles :'\n'' --unsorted

# Met à jour les dépendances composer et npm.
[group('js')]
[group('php')]
update:
    composer update
    bun update

# Formatte avec Prettier et dprint.
[group('qualité')]
format:
    bun prettier \
      --cache --cache-location ".cache/prettiercache" \
      --config "cfg/prettier.config.ts" \
      --ignore-path "cfg/prettierignore" \
      --ignore-unknown \
      --parallel-workers 8 \
      --write .
    # TwigCsFixher
    -vendor/bin/twig-cs-fixer fix web/app/themes/haiku-atelier-2024/
    # PhpCsFixer
    # -vendor/bin/php-cs-fixer fix --allow-risky yes
    dprint --config "~/.config/dprint/dprint.jsonc" fmt
    mago format
    fish scripts/format-sort-files.fish

# Compile, minifie et optimise Sass vers CSS.
[group('css')]
build-css:
    @bun sass \
        --update \
        "web/app/themes/haiku-atelier-2024/src/sass":"web/app/themes/haiku-atelier-2024/assets/css"
    @bun lightningcss \
        --bundle \
        --minify \
        --output-file "web/app/themes/haiku-atelier-2024/assets/css/main.min.css" \
        -- "web/app/themes/haiku-atelier-2024/assets/css/main.css"
    @bun lightningcss \
        --bundle \
        --minify \
        --output-file "web/app/themes/haiku-atelier-2024/assets/css/pages/page-panier.min.css" \
        -- "web/app/themes/haiku-atelier-2024/assets/css/pages/page-panier.css"
    @bun lightningcss \
        --bundle \
        --minify \
        --output-file "web/app/themes/haiku-atelier-2024/assets/css/pages/page-accueil.min.css" \
        -- "web/app/themes/haiku-atelier-2024/assets/css/pages/page-accueil.css"
    @bun lightningcss \
        --bundle \
        --minify \
        --output-file "web/app/themes/haiku-atelier-2024/assets/css/pages/page-boutique.min.css" \
        -- "web/app/themes/haiku-atelier-2024/assets/css/pages/page-boutique.css"
    @bun lightningcss \
        --bundle \
        --minify \
        --output-file "web/app/themes/haiku-atelier-2024/assets/css/pages/page-a-propos.min.css" \
        -- "web/app/themes/haiku-atelier-2024/assets/css/pages/page-a-propos.css"
    @bun lightningcss \
        --bundle \
        --minify \
        --output-file "web/app/themes/haiku-atelier-2024/assets/css/pages/page-modele-simple.min.css" \
        -- "web/app/themes/haiku-atelier-2024/assets/css/pages/page-modele-simple.css"
    @bun lightningcss \
      --bundle \
      --minify \
      --output-file "web/app/themes/haiku-atelier-2024/assets/css/pages/page-succes-commande.min.css" \
      -- "web/app/themes/haiku-atelier-2024/assets/css/pages/page-succes-commande.css"

# Compile le CSS à chaque changement de fichier.
[group('css')]
watch-css:
    @watchexec -w "web/app/themes/haiku-atelier-2024/src/sass" -- just build-css

# Compile TypeScript en JavaScript.
[group('js')]
build-js:
    @bun --bun vite build --config "cfg/vite.config.ts"

# Compile tout.
[group('css')]
[group('js')]
build-all:
    @just build-css
    @just build-js
    @just format

# Compile TypeScript à chaque changement de fichier.
[group('js')]
watch-js:
    bun vite build --watch

# Vérifie le code TypeScript avec des analyseurs statiques.
[group('js')]
[group('qualité')]
lint-js:
    -bun eslint "web/app/themes/haiku-atelier-2024/src/scripts"
    bun --bun oxlint \
    --config cfg/oxlint.config.ts \
    --format stylish

# Vérifie le code Sass avec Stylelint.
[group('css')]
[group('qualité')]
lint-css:
    -bun stylelint --config "cfg/stylelint.config.ts" "web/app/themes/haiku-atelier-2024/src/sass/" --fix

# Vérifie le code TypeScript mort avec knip
[group('js')]
[group('qualité')]
lint-code-mort:
    -bun knip

# Fusionne tous les changements actuels dans le commit précédent et pousse sur le répertoire distant avec Jujetsu.
[group('vcs')]
squash-and-push:
    -jj squash --ignore-immutable && jj bookmark set principale -r @- --allow-backwards && jj git push

# Analyse statiquement, compile et formate le CSS
[group('css')]
[group('qualité')]
lint-build-format-css:
    -just lint-css
    -just build-css
    -just format

# Lance un navigateur de développement.
[group('développement')]
dev:
    @/opt/cromite/chrome --remote-debugging-address=127.0.0.1 --remote-debugging-port=9222 --profile-directory=Guest "https://haikuatelier.gcch.local" &

# Recharge le premier onglet du navigateur de développement.
[group('développement')]
reload-tab:
    #!/usr/bin/fish
    set -f WSURL (curl -s http://127.1:9222/json | fx '.[0].webSocketDebuggerUrl')
    set -f REQUEST '{ "id": 2, "method": "Page.reload", "params": { "ignoreCache": true, "scriptToEvaluateOnLoad": "" } }'
    echo $REQUEST | websocat $WSURL

# Créé l'image OCI.
[group('container')]
build-wordpress-container:
    @podman build -t wordpress-haiku-atelier:latest --progress=plain --file "containers/Dockerfile" .

# Lance les services.
[group('container')]
up-services:
    @podman compose up -d

# Arrête les services.
[group('container')]
down-services:
    @podman compose down

# Redémarre les services.
[group('container')]
restart-services:
    @podman compose restart

# Met à jour les conteneurs images des conteneurs.
[group('container')]
pull-images:
    bun "scripts/pull-container-images.ts"

export_production_db:
    fish "scripts/déclenche-sauvegarde-bdd-production.fish"