set shell := ["fish", "-c"]

cacheFolder := ".cache"
eslintCacheFile := "eslintcache"
prettierCacheFile := "prettiercache"
stylelintCacheFile := "stylelintcache"

# Liste toutes les recettes
list:
    @just --list --list-heading 'Recettes disponibles :'\n'' --unsorted

# Démarre le conteneur ddev
start:
    ddev start

# Arrête le conteneur ddev
stop:
    ddev stop

# Met à jour les dépendances composer et npm
update:
    composer update
    pnpm update --latest

# Formatte avec Prettier et dprint
format:
    @echo "Formatage de l'ensemble du code avec Prettier et dprint."
    pnpm prettier --cache \
        --cache-location "{{ cacheFolder }}/{{ prettierCacheFile }}" \
        -u \
        --write \
        .
    dprint fmt

# Compile, minifie et optimise Sass vers CSS
build-css:
    pnpm sass \
        --update \
        "web/app/themes/haiku-atelier-2024/src/sass":"web/app/themes/haiku-atelier-2024/assets/css"
    pnpm lightningcss \
        --bundle \
        --minify \
        --output-file "web/app/themes/haiku-atelier-2024/assets/css/main.min.css" \
        --sourcemap \
        -- "web/app/themes/haiku-atelier-2024/assets/css/main.css"

# Compile le CSS à chaque changement de fichier
watch-css:
    pnpm sass \
        --update \
        --watch \
        "web/app/themes/haiku-atelier-2024/src/sass":"web/app/themes/haiku-atelier-2024/assets/css"